NCL Home > Documentation > Functions > Meteorology, Crop

refevt_turc

Use the Turc ETo formulation to derive reference evapotranspiration.

Available in version 6.4.0 and later.

Prototype

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/crop.ncl"

	function refevt_turc (
		tmean      : numeric,  
		radsol     : numeric,  
		iounit [3] : integer   
	)

Arguments

tmean

Scalar or array containing mean temperatures. he units may be derees Celcius, Kelvin or Farenheit. See the iounit argument.

radsol

A variable containing solar radiation. It must have the same dimension sizes as the tmean. See the iounit argument.

iounit

An integer array of length 3 indicating the units of input arguments tmean, radsol and the units of the returned argument.

  • iounit(0)=0 ; input tmean are in degrees C (degC).
  • iounit(0)=1 ; input tmean are in degrees K (degK).
  • iounit(0)=2 ; input tmean are in degrees F.
  • iounit(1)=0 ; input radsol are in mm/day
  • iounit(1)=1 ; input radsol are in MJ/(m2-day)
  • iounit(1)=2 ; input radsol are in W/m2
  • iounit(1)=3 ; input radsol are in cal/(cm2-day)
  • iounit(2)=0 ; output units => mm/day
  • iounit(2)=1 ; output units => MJ/(m2-day)
  • iounit(2)=2 ; output units => W/m2
  • iounit(2)=3 ; output units => cal/(cm2-day)

Return value

An array the same size as tmean containing the estimated evapotranspiration.

Description

Estimates evapotranspiration via the simple "Turc ETo" equation. This function is not described in the FAO-56 documentation. It is included because many refereed publications use this simple formulation described in the references:

         ETo = 0.013*(tmean/(tmean+15))*(radsol + 50) ; 

where radsol are in cal/(cm2-day).

Reference:
   C.-Y. Xu, V. P. Singh (2000) 
   Evaluation and generalization of radiation-based methods for calculating evaporation
   Hydrol. Process .  14 , 339-349 
   http://folk.uio.no/chongyux/papers_SCI/HYP_4.pdf

  Turc L. 1961
  Estimation of irrigation water requirements, potential evapotranspiration: 
    a simple climatic formula evolved up to date.
  Annals of Agronomy 12: 13-49

See Also

Crop & Evapotranspiration functions

Examples

Example 1: As noted, this function is not from FAO_56. Hence, there is no simple 'unit test' to which NCL can refer. Here we compare refevt_turc to that from refevt_hargreaves_fao56. The parameters are the same as Example 20, Chapter 4. for Lyon, France in mid July. Here tunit=0.

  jday   = 196                           ; 15 July
  lat    = 45.72                         ; Lyon, France
  tmin   = 14.8                          ; degC
  tmax   = 26.6
  tmean  = 0.5*(tmin+tmax)

  ra_0   = radext_fao56(jday, lat, 0)    ;  16.546 MJ/(m2-day) 
  ra_1   = radext_fao56(jday, lat, 1)    ;  40.554 mm/day 
  ra_2   = radext_fao56(jday, lat, 2)    ; 469.378 W/m2   

  print(ra_0 )                        ; print with meta data
  print("ra_1="+ra_1)
  print("ra_2="+ra_2)
  print("")
                                        ; refevt_turc requires 'radsol' (total solar radiation)
                                        ; http://www.lyon.climatemps.com/
  nsun   = 9.2                          ; 'observed' hrs/sun day
  sunhrx = daylight_fao56(jday, lat)    ; max daylight/sun; hr per day
  print(sunhrx)      ; 15.2  (matches web site)

  rs_0   = radsol_fao56(ra_0, sunhrx, nsun, (/0,0/), False)   ;    9.15 mm/day
  rs_1   = radsol_fao56(ra_1, sunhrx, nsun, (/1,1/), False)   ;   22.44 MJ/(m2-day)
  rs_2   = radsol_fao56(ra_2, sunhrx, nsun, (/2,2/), False)   ;  259.67 W/m2

  print(rs_0 )                           ; print with meta data
  print("rs_1="+rs_1 )
  print("rs_2="+rs_2 )
                                         ; illustration ... different 'rs_' yield same value
  evturc_0  = refevt_turc( tmean, rs_0, (/0,0,0/) ) ;    4.53 mm/day
  evturc_1  = refevt_turc( tmean, rs_1, (/0,1,0/) ) ;    4.53 mm/day
  evturc_2  = refevt_turc( tmean, rs_2, (/0,2,0/) ) ;    4.53 mm/day

  print(evturc_0)               ;    4.53 mm/day    will print with meta data
  print("evturc_1="+evturc_1)   ;    4.53 mm/day 
  print("evturc_0="+evt_2urc)   ;    4.53 mm/day 

NOTE: For comparison, the refevt_hargreaves_fao56 function returns estimates that differ:

         ; Hargreaves 
  evtH_000 = refevt_hargreaves_fao56( tmin, tmax, ra_0, (/0,0,0/) ) ; 5.0 mm/day
  evtH_010 = refevt_hargreaves_fao56( tmin, tmax, ra_1, (/0,1,0/) ) ; 5.0 mm/day
  evtH_020 = refevt_hargreaves_fao56( tmin, tmax, ra_2, (/0,2,0/) ) ; 5.0 mm/day  

Keep in mind that many of the reference evapotranspiration approximations were derived for applications in different regions.